ftp.sustworks.com 2018/ftp.sustworks.com.zip/ftp.sustworks.com/IPNetSentry_12.hqx/IPNetSentry_12/IPNetSentry AppleScripts/IPNS Eudora AppleScript

Text File | 2000-12-21 | 1KB | 47 lines

-- first get the trigger info from IPNetSentry
tell application "IPNetSentry.PPC"
    set theTriggerIPAddress to triggeripaddress
    set theTriggerPort to triggerport
    set theTriggerProtocol to triggerprotocol
    set theTriggerService to triggerservice
    set theTriggerTime to triggertime
    set theTriggerDate to triggerdate
    set myNotification to "IPNetSentry trigger
Remote IP Address: " & theTriggerIPAddress & "
Port: " & theTriggerPort & "
Protocol: " & theTriggerProtocol & "
Service: " & theTriggerService & "
Time: " & theTriggerTime & "
Date: " & theTriggerDate
end tell
-- now send it to us via Eudora
tell application "Eudora Pro 3.0"
    -- Create a new message in the out box
    set newMsg to make message at end of mailbox "out"

    -- Message 0 indicates the current message
    -- Set the recipient of the message
    set field "to" of newMsg to "TO_EMAIL_ADDRESS"

    -- Set who the message is from;
    -- This must be set to a valid address so that you can receive replies
    set field "from" of newMsg to "FROM_EMAIL_ADDRESS"

    -- set the subject of the message
    set field "subject" of newMsg to "IPNetSentry Tigger Alert"

    -- set the cc recipients of the message
    -- set field "cc" of newMsg to "[e-mail]"

    -- set the bcc recipients of the message
    -- set field "bcc" of newMsg to "[e-mail]"

    -- set the body of the message
    -- field "" indicates the body of the message
    set field "" of newMsg to myNotification

    queue newMsg
    connect
end tell